第16章习题

站长

第16章习题

1．修改代码清单16-1和15-3，使用户程序能够正常返回到内核，并在显示消息后停机。
答案：将jmp far [fs:TerminateProgram]改为call far [fs:TerminateProgram]。

2．修改代码清单16-1和15-3，使得通过调用门请求读取硬盘扇区的服务时，通过栈传递参数。而且，传递的参数分别是逻辑扇区号、数据段选择子和段内偏移。要求使用arpl指令。
参考答案：
内核程序较为复杂，尽量不改变原有的设计和元素，仅添加新的功能较好。为此，我们需要在内核公用例程段内新增加一个例程read_hard_disk_with_gate并用它创建一个新的调用门。以下是这个新例程的代码。

1. ;此例程用于说明如何通过请求特权级RPL解决因请求者身份与CPL不同而带来的安全问题
   
2. read_hard_disk_with_gate:                   ;从硬盘读取一个逻辑扇区
   
3.                                             ;输入：PUSH 逻辑扇区号
   
4.                                             ;      PUSH 目标缓冲区在段内的偏移量
   
5.                                             ;      PUSH 目标缓冲区所在段的选择子
   
6.                                             ;返回：无
   
7.          push ebp
   
8.          mov ebp,esp
   
9. 
   
10.          push eax
    
11.          push ebx
    
12.          push ds
    
13. 
    
14.          mov ax,[ebp+0x08]                  ;获取调用者的CS
    
15.          arpl [ebp+0x0c],ax                 ;将数据段选择子调整到真实的请求特权级别
    
16.          mov ds,[ebp+0x0c]                  ;用真实的段选择子加载段寄存器DS
    
17. 
    
18.          mov eax,[ebp+0x14]                 ;从栈中取得逻辑扇区号
    
19.          mov ebx,[ebp+0x10]                 ;从栈中取得缓冲区在段内的偏移量
    
20. 
    
21.          ;此部分的功能是读硬盘，并传送到缓冲区。调用现成的例程。
    
22.          call sys_routine_seg_sel:read_hard_disk_0
    
23. 
    
24.          pop ds
    
25.          pop ebx
    
26.          pop eax
    
27. 
    
28.          pop ebp
    
29. 
    
30.          retf 12                        ;必须是参数的总字节数

复制代码

接下来，转到内核数据段，在原来的符号地址检索表末尾添加一个新的条目：

1.          salt_5         db  '@ReadDiskDataWithGate'
   
2.                      times 256-($-salt_5) db 0
   
3.                           dd  read_hard_disk_with_gate
   
4.                           dw  sys_routine_seg_sel

复制代码

注意修改salt_item_len，将其改为

1. salt_item_len   equ $-salt_5

复制代码

再转到内核的入口点，找到安装调用门的循环代码。这段代码不能处理调用门中的参数数量部分，所以要将其删除，手动逐个安装调用门。实施：删除原来的循环，插入以下代码：

1.          ;以下开始安装为整个系统服务的调用门。特权级之间的控制转移必须使用门
   
2.          ;安装'PrintString'
   
3.          mov eax,[salt_1+256]               ;该条目入口点的32位偏移地址
   
4.          mov bx,[salt_1+260]                ;该条目入口点的段选择子
   
5.          mov cx,1_11_0_1100_000_00000B      ;特权级3的调用门(3以上的特权级才
   
6.                                             ;允许访问)，0个参数(因为用寄存器
   
7.                                             ;传递参数，而没有用栈)
   
8.          call sys_routine_seg_sel:make_gate_descriptor
   
9.          call sys_routine_seg_sel:set_up_gdt_descriptor
   
10.          mov [salt_1+260],cx                ;将返回的门描述符选择子回填
    
11. 
    
12.          ;安装'ReadDiskData'
    
13.          mov eax,[salt_2+256]               ;该条目入口点的32位偏移地址
    
14.          mov bx,[salt_2+260]                ;该条目入口点的段选择子
    
15.          mov cx,1_11_0_1100_000_00000B      ;特权级3的调用门(3以上的特权级才
    
16.                                             ;允许访问)，0个参数)
    
17.          call sys_routine_seg_sel:make_gate_descriptor
    
18.          call sys_routine_seg_sel:set_up_gdt_descriptor
    
19.          mov [salt_2+260],cx                ;将返回的门描述符选择子回填
    
20. 
    
21.          ;安装'PrintDwordAsHexString'
    
22.          mov eax,[salt_3+256]               ;该条目入口点的32位偏移地址
    
23.          mov bx,[salt_3+260]                ;该条目入口点的段选择子
    
24.          mov cx,1_11_0_1100_000_00000B      ;特权级3的调用门(3以上的特权级才
    
25.                                             ;允许访问)，0个参数(因为用寄存器
    
26.                                             ;传递参数，而没有用栈)
    
27.          call sys_routine_seg_sel:make_gate_descriptor
    
28.          call sys_routine_seg_sel:set_up_gdt_descriptor
    
29.          mov [salt_3+260],cx                ;将返回的门描述符选择子回填
    
30. 
    
31.          ;安装'TerminateProgram'
    
32.          mov eax,[salt_4+256]               ;该条目入口点的32位偏移地址
    
33.          mov bx,[salt_4+260]                ;该条目入口点的段选择子
    
34.          mov cx,1_11_0_1100_000_00000B      ;特权级3的调用门(3以上的特权级才
    
35.                                             ;允许访问)，0个参数(因为用寄存器
    
36.                                             ;传递参数，而没有用栈)
    
37.          call sys_routine_seg_sel:make_gate_descriptor
    
38.          call sys_routine_seg_sel:set_up_gdt_descriptor
    
39.          mov [salt_4+260],cx                ;将返回的门描述符选择子回填
    
40. 
    
41.          ;安装'ReadDiskDataWithGate'
    
42.          mov eax,[salt_5+256]                  ;该条目入口点的32位偏移地址
    
43.          mov bx,[salt_5+260]                   ;该条目入口点的段选择子
    
44.          mov cx,1_11_0_1100_000_00011B      ;特权级3的调用门(3以上的特权级才
    
45.                                             ;允许访问)，3个参数。
    
46.          call sys_routine_seg_sel:make_gate_descriptor
    
47.          call sys_routine_seg_sel:set_up_gdt_descriptor
    
48.          mov [salt_5+260],cx                   ;将返回的门描述符选择子回填

复制代码

接下来修改用户程序c15_app.asm。
由于是使用内核中新添加的调用门，所以要在头部段中，将

1.          ReadDiskData     db  '@ReadDiskData'
   
2.                      times 256-($-ReadDiskData) db 0

复制代码

修改为

1.          ReadDiskData     db  '@ReadDiskDataWithGate'
   
2.                      times 256-($-ReadDiskData) db 0

复制代码

既然是通过栈传递参数，那就删除第74~77行，插入以下指令：

1.         push dword 100                ;压入起始逻辑扇区号
   
2.         push dword buffer        ;压入段内偏移量
   
3.         push ds                        ;压入数据段选择子
   
4.         call far [fs:ReadDiskData]          ;段间调用

复制代码

为保证程序正常工作，将代码段最后的

1. jmp far [fs:TerminateProgram]

复制代码

改成

1. call far [fs:TerminateProgram]

复制代码

由于文件较大，这里将它作为附件发布。